Power Apps Deep Links: Email Direct Link To A Specific Record

Deep links are a type of hyperlink that send an app user to a specific record or screen. In Power Apps deep links are most useful when sent in an email. The recipient can click on a deep link to open an app and immediately navigate to the information they need with no extra effort. In this article I will show you how to send an email with deep links that immediately open Power Apps to a specific record or screen.

Table Of Contents
Introduction: The Create A Support Ticket App
Setup The SharePoint List
Create An Edit Form
Make A Submit Button For The Edit Form
Get the Canvas App Web Link
Send An Email With A Direct Link To A Specific Record
Obtain A Record ID From The App OnStart
Submit A Support Ticket To Generate An Email
Build A Gallery Showing All Support Tickets
Define The App StartScreen Property

Introduction: The Create A Support Ticket App

The Create A Support Ticket app is used by employees at a manufacturing company to ask the I/T department for help with technology related issues. After a support ticket is submitted, the employee receives and email with a link that allows them to go back and review the support ticket they created in the system.

Setup The SharePoint List

Create a new SharePoint list called Support Tickets with the following columns:

• ID (whole number column)
• Title (single-line text)
• IssueType (choice) [Options: Desktop/Laptop, Business Application, Internet, Virus]
• Description (multiple line text)
• Created (person column)
• Created By (date & time column)
  

It is not necessary to create the columns ID, Created and Created By since they are included by default in any SharePoint list. However, we we must unhide them by going the the Show/Hide Columns menu and checking the box beside their columns names.

Once created the Support Tickets SharePoint list does not require any data to be loaded. We will make some new support tickets while building the app.

ID	Title	IssueType	Description	Created	CreatedBy

Create An Edit Form

When an employee opens the Create A Support Ticket app they fill-in a form with details about their technology issue and submit the form to the I/T department. Open a Power Apps Studio and make a new canvas app from blank. Then add a label to the top to act as a titlebar.

Connect the Support Tickets SharePoint list to the app.

Then insert an Edit Form and select Support Tickets as the datasource for the the form.

Include only the Title, Issue Type and Description fields in the form. The fields ID, Created and Created By will be automatically generated when a new support ticket is created.

Also, change the DefaultMode property of the app to this code to specify that a new record should be added to the SharePoint list when the form is submitted.

FormMode.New

Make A Submit Button For The Edit Form

Now that the form is finished we need to add a submit button. Insert a new button below the form with the text “Submit”.

Use this code in the OnSelect property of the form to submit the form details to the SharePoint list.

SubmitForm(frm_Form_Support)

Then add this code to the OnSuccess property of the form to define what happens after the new ticket is successfully created. We want to capture the ticket details in a variable called varRecordTicket, change the form to view-mode and then show a banner at the top of the screen to let the employee know their ticket was saved.

Set(varRecordTicket, frm_Form_Support.LastSubmit);
ViewForm(frm_Form_Support);
Notify("Success: Your support ticket was submitted", NotificationType.Success);

Put this code in the Item property of the form so it knows which record to display while in view-mode…

varRecordTicket

…and finally, use this code in the Visible property of the submit button to hide it after the ticket is submitted.

frm_Form_Support.Mode<>FormMode.View

Get the Canvas App Web Link

To generate a direct link to the submitted ticket we must first obtain the app’s web link. Save and publish the Create A Support Ticket app then open the make.powerapps.com and click the three dots beside the app’s name. Select the details menu item.

The web link can be found on the details tab.

Copy the web link into windows notepad or some other note taking app. We will need it in just a moment.

https://apps.powerapps.com/play/d77ba81c-d7e4-4131-bb06-12b172225819?tenantId=f1b8b509-50a4-4a5c-8e48-bf3d3e7c10ed

Send An Email With A Direct Link To A Specific Record

After a support ticket is submitted employees will receive an email with a direct link to the support ticket in Power Apps. Go to Power Automate and build a new automated cloud flow called Support Tickets: Send Notification Email. Choose When an item is created for the trigger.

Add two actions to the flow: Compose (Data Operations) and Send An Email V2 (Outlook). Fill-in the actions as shown in the image below.

In the compose step of the flow we are writing HTML code to insert into the body of the notification email. The direct link to a specific record can be found inside the <a> tags. We take the web link for the app and add a URL parameter called supportticketid. This parameter is filled with the unique ID number from the Support Tickets SharePoint list.

<html>

<body>

You submitted a support ticket.  To check the details of your support ticket please click on the link below.<br>
<br>

<a href="https://apps.powerapps.com/play/d77ba81c-d7e4-4131-bb06-12b172225819?tenantId=f1b8b509-50a4-4a5c-8e48-bf3d3e7c10ed&supportticketid=@{triggerOutputs()?['body/ID']}">Link To Support Ticket</a>

</body>

</html>

Save and close the flow. We will test the deep link soon, but first, we must make some more changes to the app.

Obtain A Record ID From The App OnStart Property

When the app opens it must check whether a record ID was supplied inside the supportticketid URL parameter. If supportticketid has a value, the form should display that record, otherwise, it will appear blank.

Use this code in the OnStart property of the app. It performs a lookup on the supportticketid URL parameter and stores the result in the varRecordTicket variable. If a record was found it changes the form to view mode (instead of new mode which is the default we setup earlier).

Set(
    varRecordTicket,
    LookUp(
        'Support Tickets',
        ID = Value(Param("supportticketid"))
    )
);
If(
    !IsBlank(varRecordTicket),
    ViewForm(frm_Form_Support)
)

We will also make another small modification to the titlebar’s text.

When the form is in new mode the titlebar will show the text “Create A Support Ticket”, otherwise, it will display the ticket ID number. Use this code in the Text property of the titlebar.

If(
    frm_Form_Support.Mode=FormMode.New,
    "Create A Support Ticket",
    "Support Ticket #"&varRecordTicket.ID
)

Submit A Support Ticket To Generate An Email

We can now test our app to confirm it generates and email with a direct link to the submitted record. Fill-in the support ticket form with the data shown below.

Then wait a few moments and an email will appear with a direct link to the support ticket record. Click on the link.

When we click on the link the app opens with the form in view-mode and displays the support ticket details.

Build A Gallery Showing All Support Tickets

The Create A Support Ticket app also has another screen where an employee can see all of the support tickets they have submitted. After making this new screen we will tell our app which screen it should open to: the Support Ticket List Screen or the Support Ticket Form screen.

Add a new blank screen to the app and insert a gallery. Connect the gallery to the Support Tickets SharePoint list.

Change the gallery layout to Title, subtitle and body.

Then update the gallery data fields to the values shown in the image below.

When an employee clicks on a support ticket they should be able to view its details and perform edits.

Put this code in the OnSelect property of the gallery.

Set(varRecordTicket, ThisItem);
EditForm(frm_Form_Support);
Navigate('Support Ticket Form Screen', Fade);

We also need a way for employees to add new tickets. Insert an add icon at the top of the screen…

…then use this code in the OnSelect property of the icon.

Set(varRecordTicket, Blank());
NewForm(frm_Form_Support);
Navigate('Support Ticket Form Screen', Fade);

One more thing. Once the employee arrives at the form screen they need a way to get back to the list screen. Place a left arrow icon in the top left corner of the form screen.

Then write this code in the OnSelect property of the icon.

Navigate('Support Ticket List Screen')

Define The App StartScreen Property

Once the app is opened it must determine which screen to load: the support ticket list screen or the support ticket form screen.

We do this by writing an if statement in the the StartScreen property of the app. If the supportticketid URL parameter is blank the app opens to the list screen. But if supportticketid does have a value then the app opens to the form screen.

If(
    IsBlank(Param("supportticketid")),
    'Support Ticket List Screen',
    'Support Ticket Form Screen'
)

Questions?

If you have any questions or feedback about Power Apps Deep Links: Email Direct Link To A Specific Record please leave a message in the comments section below. You can post using your email address and are not required to create an account to join the discussion.